Setup apt cron job, install/purge base packages
[cacert-puppet.git] / sitemodules / profiles / manifests / base.pp
1 # Class: profiles::base
2 # =====================
3 #
4 # This class defines the base profile that is valid for all puppet managed
5 # CAcert hosts and should therefore be included in any host role class in the
6 # roles module.
7 #
8 # Parameters
9 # ----------
10 #
11 # @param admins a list of admin users for the node
12 #
13 # @param users a hash containing user information
14 #
15 # Examples
16 # --------
17 #
18 # @example
19 # class roles::myhost {
20 # include profiles::base
21 # }
22 #
23 # Authors
24 # -------
25 #
26 # Jan Dittberner <jandd@cacert.org>
27 #
28 # Copyright
29 # ---------
30 #
31 # Copyright 2016-2018 Jan Dittberner
32 #
33 class profiles::base (
34 Array[String] $admins = [],
35 Hash[String, Data] $users = {},
36 ) {
37 # ensure admin users for this container
38 $admins.each |String $username| {
39 $user = $users[$username]
40 $osusername = $user['username']
41 group { $user['username']:
42 ensure => present,
43 } ->
44 user { $osusername:
45 ensure => present,
46 comment => $user['fullname'],
47 gid => $osusername,
48 groups => ['sudo', 'adm'],
49 password => $user['password'],
50 uid => $user['uid'],
51 home => "/home/${osusername}",
52 shell => $user['shell'],
53 purge_ssh_keys => true,
54 managehome => true,
55 }
56 $user['ssh_keys'].each |Hash[String, Data] $keydata| {
57 $keyname = $keydata['name']
58 ssh_authorized_key { "${osusername}@${keyname}":
59 ensure => present,
60 user => $user['username'],
61 type => $keydata['type'],
62 key => $keydata['key'],
63 require => User[$osusername],
64 }
65 }
66 }
67
68 file { '/etc/init.d/puppet':
69 ensure => file,
70 owner => 'root',
71 group => 'root',
72 mode => '0755',
73 source => 'puppet:///modules/profiles/puppet.init',
74 }
75
76 file { '/etc/apt/apt.conf.d/03proxy':
77 ensure => file,
78 owner => 'root',
79 group => 'root',
80 mode => '0644',
81 source => 'puppet:///modules/profiles/base/apt_proxy.conf',
82 }
83 file { '/etc/apt/apt.conf.d/10periodic':
84 ensure => file,
85 owner => 'root',
86 group => 'root',
87 mode => '0644',
88 source => 'puppet:///modules/profiles/base/apt_periodic.conf',
89 }
90
91 package { 'lsb-release':
92 ensure => present,
93 }
94
95 package { ['zsh', 'tmux', 'less']:
96 ensure => latest,
97 }
98 package { ['aptitude', 'apticron']:
99 ensure => purged,
100 }
101
102 file { '/etc/apt/sources.list':
103 ensure => file,
104 owner => 'root',
105 group => 'root',
106 mode => '0644',
107 content => epp(
108 'profiles/base/apt_sources.list.epp',
109 {'oscodename' => $facts['os']['distro']['codename']}),
110 require => Package['lsb-release'],
111 }
112 file { '/etc/apt/sources.list.d/puppetlabs-pc1.list':
113 ensure => absent,
114 }
115 file { '/etc/apt/sources.list.d/puppet5.list':
116 ensure => file,
117 owner => 'root',
118 group => 'root',
119 mode => '0644',
120 content => epp(
121 'profiles/base/apt_sources_puppet5.list.epp',
122 {'oscodename' => $facts['os']['distro']['codename']}),
123 require => Package['lsb-release'],
124 }
125
126 file { '/etc/apt/preferences.d/blacklist_systemd-sysv.pref':
127 ensure => file,
128 owner => 'root',
129 group =>'root',
130 mode => '0644',
131 source => 'puppet:///modules/profiles/base/apt_blacklist_systemd-sysv.pref',
132 }
133 }